yum::versionlock doesn't work as documented

[vchepkov]

on RHEL9, when trying to implement versionlock, catalog fails to compile

profile::yum::versionlock:
  - candlepin-0:4.4.10-1.el9.*
  - candlepin-selinux-0:4.4.10-1.el9.*

  if $versionlock {
    $versionlock.each | String $v| {
      yum::versionlock { $v: }
    }
  }

Error: Could not retrieve catalog from remote server: Error 500 on SERVER: Server Error: Evaluation Error: Error while evaluating a Resource Statement, Evaluation Error: Error while evaluating a Function Call, Package name must be formatted as Yum::RpmName, not 'String'. See Yum::Rpmname documentation for details. (file: /opt/puppetlabs/server/data/puppetserver/filesync/client/versioned-dirs/puppet-code/production_90afc15b2dd89dcb859edafd5768f4efb3da9462/modules/yum/manifests/versionlock.pp, line: 80, column: 7) (file: /etc/puppetlabs/puppetserver/code/environments/production/site/profile/manifests/yum.pp, line: 39) on node foreman.chepkov.lan

The strings are created by dnf versionlock command

[vchepkov]

I have refactored, but imho, the previous parameters format should be accepted

profile::yum::versionlock:
  candlepin:
    version: 4.4.10
  candlepin-selinux:
    version: 4.4.10

  if $versionlock {
    $versionlock.each |String $package, Hash $attributes| {
      yum::versionlock { $package:
        * => $attributes,
      }
    }
  }

[sbrowne-godaddy]

We had the same issue, so use a wrapper define like this:

define profile::versionlock (
  Enum['present', 'absent', 'exclude'] $ensure  = 'present',
  Optional[Yum::RpmVersion]            $version = undef,
  Yum::RpmRelease                      $release = '*',
  Integer[0]                           $epoch   = 0,
  Variant[Yum::RpmArch, Enum['*']]     $arch    = '*',
) {

  if ($facts['os']['family'] == 'RedHat' and versioncmp($facts['os']['release']['major'], '7') > 0) {
    if ($version =~ Yum::RpmVersion) {
      $_name    = $title
      $_version = $version
      $_release = $release
      $_epoch   = $epoch
      $_arch    = $arch
    } elsif ($title =~ /^([0-9]+):(.+)-([0-9.-S]+)-(.+)\.([nsaix\*].+)$/) {
      $_name    = $2
      $_version = $3
      $_release = $4
      $_epoch   = Integer.new($1)
      $_arch    = $5
    }
  } else {
    $_name    = $title
    $_version = undef
    $_release = undef
    $_epoch   = undef
    $_arch    = undef
  }

  yum::versionlock { $_name:
    ensure  => $ensure,
    version => $_version,
    release => $_release,
    epoch   => $_epoch,
    arch    => $_arch,
  }
}

[patchsmyle]

Hello All, I recommend to take a close look. On RHEL 9, when running the puppet facts the "package_provider" is not 'yum', but 'dnf'.

Referring to

puppet-yum/manifests/versionlock.pp

Line 70 in 53dde4e

if $facts['package_provider'] == 'yum' and $version =~ Undef {

[root]# puppet facts package_provider
{
  "package_provider": "dnf"
}
[root@]# cat /etc/redhat-release 
Red Hat Enterprise Linux release 9.4 (Plow)
[root@]# 

Thusly, the code to fix the line 70 should be, and things will resume working.

if $facts['package_provider'] in ['yum', 'dnf'] and $version =~ Undef {