Second call to WiFi.begin() + ArduinoOTA running seems to block forever on RP2040

[ledereyes]

Hi, I am trying to implement proper WiFi reconnect handling, but it seems the second time I am calling WiFi.begin it blocks forever. This is my logic called from loop:

  if (!WiFi.isConnected())
  {
    Serial.println("connection lost");
    if (WiFi.begin(ssid, pass) != WL_CONNECTED) // seems to block forever
    {
      Serial.println("wifi reconnect failed");
    }
    else
    {
      Serial.println("wifi reconnect success");
    }
  }

I am triggering the disconnect by powering off and on my router. The last message I get over Serial is "connection lost" which makes me believe that WiFi.being blocks.
What I tried so far:

1. Using the async version WiFi.beginNoBlock but it also never returns.
2. Adding various delays here and there.
3. Calling WiFi.disconnect and WiFi.end before the reconnect.
4. An RP2350

These are my versions:

[env:rpipicow]
platform = https://github.com/maxgerhardt/platform-raspberrypi.git#a4b555a5f29961fd76e278b3c5ba56f0067207d0
framework = arduino
board_build.core = earlephilhower
board_build.filesystem_size = 0.5m
board = rpipicow

Thanks for any help on the issue!

[earlephilhower]

I can't reproduce any such failure here. I set up another PicoW as the server (using the CaptivePortal example and renaming the WiFi network to "picow" because I didn't want to have to type that loooong name it used) and ran the following test which does what you've described above:

#include <WiFi.h>

void setup() {
  delay(5000);
  WiFi.setHostname("DUT");
  Serial.println("Starting WiFi");
  WiFi.begin("picow");
  Serial.printf("IP: %s\n", WiFi.localIP().toString().c_str());
}

void loop() {
  static int l = 0;
  Serial.printf("loop %d\n", l);
  if (!WiFi.connected()) {
    Serial.println("Attempting reconnect...");
    Serial.flush();
    if (WiFi.begin("picow") == WL_CONNECTED) {
      Serial.printf("IP: %s\n", WiFi.localIP().toString().c_str());
    } else {
      Serial.println("Failed\n");
    }
  }
  delay(50); // do something;
  l++;
}

I ran for a while with the AP PicoW running, then pulled the plug. I then saw it attempt to reconnect multiple times and finally succeed and go on its way once I repowered the AP PicoW:

....
loop 567
loop 568
loop 569
Attempting reconnect...
Failed

loop 570
Attempting reconnect...
Failed

loop 571
Attempting reconnect...
Failed

loop 572
Attempting reconnect...
12:49:16.694 -> Failed
12:49:16.694 -> 
12:49:16.723 -> loop 573
12:49:16.723 -> Attempting reconnect...
12:49:46.726 -> Failed
12:49:46.726 -> 
12:49:46.796 -> loop 574
12:49:46.796 -> Attempting reconnect...
12:50:16.779 -> Failed
12:50:16.779 -> 
12:50:16.846 -> loop 575
12:50:16.846 -> Attempting reconnect...
12:50:19.586 -> IP: 172.217.28.16
12:50:19.649 -> loop 576
12:50:19.682 -> loop 577
12:50:19.749 -> loop 578
12:50:19.782 -> loop 579
12:50:19.848 -> loop 580

You can see each connect has a 30s timeout from the timestamps. That's in the SDK and you can go with an async WiFi.begin (like in the ESP devices) by using WiFi.mode(WIFI_STA) before the begin call, but then you obviously need to implement a basic FSM to track connection state.

[earlephilhower]

If you can provide an small, complete MCVE that shows the problem we can see if there's something the above test is missing, OTW there's not really anything showing here to go on...

[earlephilhower]

@ledereyes I noticed that the WiFi timeout was set to 15s, but it took 30s to timeout in the app. So I started digging and ended up actually removing and rewriting the SDK WiFi connection routine. That exposed another bug which maybe you're hitting, namely that if the low-level WiFi driver fails to connect we could end up with a dangling netif in LWIP which would cause a panic when the next pass through came and we tried to add the same one.

In any case, give #3160 a try and report back if you can. I know it fixes the double-timeout issue (and can explain how, unlike my 4 year old hack which makes me scratch my head today) and one way LWIP could crash.

[ledereyes]

Thanks a lot for looking into the issue @earlephilhower !

Unfortunately the new commit does still not fix my issue. But since the sketch you posted worked for me it was clear that it must be something else in my sketch that causes the problem.

So I went step by step and added the rest of my code and it seems that OTA is causing the freeze:

#include <WiFi.h>
#include <ArduinoOTA.h>

const char * ssid ="";
const char * pass ="";

void setupOTA()
{
  ArduinoOTA.setPort(2040);
  ArduinoOTA.onStart([]()
  {
    String type;
    if (ArduinoOTA.getCommand() == U_FLASH) {
      type = "sketch";
    } else {  // U_FS
      type = "filesystem";
    }
    // NOTE: if updating FS this would be the place to unmount FS using FS.end()
    Serial.println("Start updating " + type); 
  });

  ArduinoOTA.onEnd([]()
  {
     Serial.println("\nEnd");
     rp2040.reboot(); 
  });

  ArduinoOTA.onProgress([](unsigned int progress, unsigned int total)
  {
    Serial.printf("Progress: %u%%\r", (progress / (total / 100))); 
  });

  ArduinoOTA.onError([](ota_error_t error)
  {
    Serial.printf("Error[%u]: ", error);
    if (error == OTA_AUTH_ERROR) {
      Serial.println("Auth Failed");
    } else if (error == OTA_BEGIN_ERROR) {
      Serial.println("Begin Failed");
    } else if (error == OTA_CONNECT_ERROR) {
      Serial.println("Connect Failed");
    } else if (error == OTA_RECEIVE_ERROR) {
      Serial.println("Receive Failed");
    } else if (error == OTA_END_ERROR) {
      Serial.println("End Failed");
    } 
  });

  ArduinoOTA.begin();
  Serial.println("OTA begin");
}

void setup() {
  delay(5000);
  WiFi.setHostname("DUT");
  Serial.println("Starting WiFi");
  WiFi.begin(ssid, pass);
  Serial.printf("IP: %s\n", WiFi.localIP().toString().c_str());

  setupOTA();
}

void loop() {
  static int l = 0;
  Serial.printf("loop %d\n", l);
  if (!WiFi.connected()) {
    Serial.println("Attempting reconnect...");
    Serial.flush();
    if (WiFi.begin(ssid, pass) == WL_CONNECTED) {
      Serial.printf("IP: %s\n", WiFi.localIP().toString().c_str());
    } else {
      Serial.println("Failed\n");
    }
  }
  delay(50); // do something;
  l++;
}

Besides that I noticed that a combination of WiFi.end() plus a delay(1000) between the disconnect and the reconnect attempt does not lead to the freeze!