storage 'local-lvm' does not exist

[Tydorius]

I'm aware that datastore_id will default to 'local-lvm' if it's not set in some cases, but I've set it in both of these cases and it's giving me the following error when I try to apply:

proxmox_virtual_environment_vm.docker-vm[0]: Creating... ╷ │ Error: error waiting for VM creation: task "UPID:hl-pm-01:0003AF49:00508772:67C0FA2E:qmcreate:1001:root@pam:" failed to complete with exit code: unable to create VM 1001 - storage 'local-lvm' does not exist │ │ with proxmox_virtual_environment_vm.docker-vm[0], │ on main.tf line 17, in resource "proxmox_virtual_environment_vm" "docker-vm": │ 17: resource "proxmox_virtual_environment_vm" "docker-vm" { │

My main.tf code is below. The cloud image is pulled to nfsstorage, but I want the actual VM disk to be within local-zfs. Have I missed something? The image itself downloaded fine as well, it's failing on the VM creation task qmcreate. I've tried searching for "'local-lvm' does not exist" but did not find any similar discussions.

terraform {
  required_providers {
    proxmox = {
      source = "bpg/proxmox"
      version = "0.73.0"
    }
  }
}

provider "proxmox" {
  endpoint = var.api_url
  username = "root@pam"
  password = var.pass
  insecure = true
}

resource "proxmox_virtual_environment_vm" "docker-vm" {
  count = 1
  name      = var.docker-hosts[count.index]
  node_name = var.proxmox-hosts[count.index]
  vm_id = var.vmids[count.index]

  # should be true if qemu agent is not installed / enabled on the VM
  stop_on_destroy = true

  initialization {
    user_account {
      username = "root"
      password = var.docker_pw
    }
    ip_config {
      ipv4 {
        address = "${var.docker-base-ip}${var.docker-ips[count.index]}${var.docker-subnet}"
        gateway = var.gw[0]
      }
    }
  }

  startup {
    order      = count.index
    up_delay   = "60"
    down_delay = "60"
  }
 
  cpu {
    cores        = 8
    type         = "x86-64-v2-AES"  # recommended for modern CPUs
  }

  memory {
    dedicated = 6144
    floating  = 512 # set equal to dedicated to enable ballooning
  }

  disk {
    datastore_id = "local-zfs"
    file_id      = proxmox_virtual_environment_download_file.ubuntu_cloud_image.id
    interface    = "virtio0"
    iothread     = true
    discard      = "on"
    size         = 100
  }  

  network_device {
    bridge = "vmbr0"
  }
  
  
}

resource "proxmox_virtual_environment_download_file" "ubuntu_cloud_image" {
  content_type = "iso"
  datastore_id = "nfsstorage"
  node_name    = var.proxmox-hosts[0]
  url          = "https://cloud-images.ubuntu.com/noble/current/noble-server-cloudimg-amd64.img"
}

[bpg]

Hey @Tydorius! 👋🏼

I think you're missing datastore_id under initialization. Not obvious, I admit, but a cloud-init "drive" configured by the initialization block needs to be stored somewhere 😅

[Tydorius]

That did it! I never thought to put datastore_id anywhere else as I didn't see it in initialization for any of the examples. I spent two hours bashing my head against this. Thanks for the clarification!