plugins {
    id("com.stochastictinkr.lwjgl") version "1.0.3"
}

dependencies {
    lwjgl {
        /* Specify the LWJGL version. Defaults to 3.3.6 */
        version = "3.3.6"
        /* Or you can specify the version directly from a version catalog: */
        version(libs.versions.lwjgl3)

        /* You can override the group ID of the LWJGL dependencies, if you're using a forked version: */
        group = "com.example.lwjgl" // Default is "org.lwjgl"

        /* You can specify a list of LWJGL modules you want to include: */
        modules(
            /* `core` is always included.*/
            shaderc,
            freetype,
        )

        /* You can also specify a set of modules using presets: */
        presets.minimalOpenGL()

        /* 
          You can specify multiple presets:
         */
        presets {
            minimalOpenGL()
            minimalVulkan()
        }

        /*
         By default, presets filter our modules that are not present in the selected version of LWJGL.
         You can disable this behavior by setting `presets.filterMinVersion = false`.
         */
        presets.filterMinVersion = false
        // or
        presets {
            filterMinVersion = false
        }

        /* You can override which native platforms (binaries) to include. */
        nativePlatforms(linuxArm64, windows)

        /* You can also specify all native platforms */
        useAllNativePlatforms()

        /* 
          If you don't specify any natives, it will default to auto-detecting the current platform.
          You can query the current platform from `runningPlatform`.
         */
        println("Current platform: $runningPlatform")

        /* 
          You can update which configurations will get the LWJGL dependencies.
          - Java dependencies are added to the configuration specified by `implementationConfiguration`
          - Native dependencies are added to the configuration specified by `runtimeConfiguration`.
          
          implementationConfiguration and runtimeConfiguration default to "implementation" and "runtimeOnly" respectively.
         */
        // implementationConfiguration = "implementation"
        // runtimeConfiguration = "runtimeOnly"

        /* You can use modules and platforms that are not included in this plugin. */
        modules(
            Module(
                name = "another-module",
                // hasNatives = true, // defaults to true
                // artifactId = "lwjgl-another-module" // defaults to "lwjgl-$name"
                // minVersion = "3.3.6" // Only used by presets, so not required to set.
            ),
        )
        platforms(Platform("another-platform"))
    }
}