feat: add nix flake

README.md

@@ -37,6 +37,46 @@ Needs [Python 3.11](https://www.python.org/downloads/release/python-3119)+ insta
 pip install senpwai
 ```
 
+-   **NixOS**
+
+Add this repo's flake to your flake inputs
+
+```
+# flake.nix
+{
+  # ...
+  inputs = {
+    senpwai = {
+      type = "github";
+      owner = "SenZmaKi";
+      repo = "Senpwai";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+  # ...
+}
+```
+
+then install the package provided by the flake by adding it to either `environment.systemPackages` or `home.packages`
+
+> With `environment.systemPackages` (nixosModules)
+  ```
+    { inputs, ... }: {
+      environment.systemPackages = [
+        inputs.senpwai.packages.x86_64-linux.default
+      ];
+    }
+  ```
+
+> With `home.packages` (home-manager)
+ ```
+    { inputs, ... }: {
+      home.packages = [
+        inputs.senpwai.packages.x86_64-linux.default
+      ];
+    }
+  ```
+
 -   **Android**
 
 Check [Senpcli](https://github.com/SenZmaKi/Senpwai/blob/master/docs/senpcli-guide.md)

default.nix

@@ -0,0 +1,77 @@
+{
+  makeDesktopItem,
+  buildPythonPackage,
+  pythonRelaxDepsHook,
+  poetry-core,
+  setuptools,
+  wheel,
+  glib,
+  imagemagick,
+  requests,
+  yarl,
+  anitopy,
+  appdirs,
+  tqdm,
+  pylnk3,
+  pyqt6,
+  cryptography,
+  beautifulsoup4,
+}: let
+  pname = "senpwai";
+  version = "2.1.15";
+
+  desktopItem = makeDesktopItem {
+    name = "${pname}";
+    desktopName = "Senpwai";
+    exec = "${pname}";
+    icon = "${pname}";
+    terminal = false;
+    categories = ["Utility"];
+  };
+in
+  buildPythonPackage {
+    inherit pname version;
+
+    src = ./.;
+
+    format = "pyproject";
+
+    build-system = [
+      setuptools
+      wheel
+      poetry-core
+    ];
+
+    nativeBuildInputs = [
+      glib
+      pythonRelaxDepsHook
+    ];
+
+    propagatedBuildInputs = [
+      glib
+      wheel
+      poetry-core
+      requests
+      yarl
+      anitopy
+      appdirs
+      tqdm
+      pylnk3
+      pyqt6
+      cryptography
+      beautifulsoup4
+    ];
+
+    pythonRemoveDeps = [
+      "cryptography"
+      "argparse"
+      "bs4"
+    ];
+
+    doCheck = false;
+    postInstall = ''
+      mkdir -p "$out/share/pixmaps"
+      ${imagemagick}/bin/magick $src/senpwai/assets/misc/senpwai-icon.ico "$out/share/pixmaps/${pname}.png"
+      cp -r ${desktopItem}/share/applications $out/share
+    '';
+  }

flake.nix

@@ -0,0 +1,20 @@
+{
+  description = "A flake to install Senpwai";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    system = "x86_64-linux";
+    pkgs = nixpkgs.legacyPackages.${system};
+  in {
+    packages.${system} = {
+      senpwai = pkgs.python312Packages.callPackage ./default.nix {};
+      default = self.packages.${system}.senpwai;
+    };
+  };
+}