Pull a row from an array and convert the values to string

[Alastair-Bailey]

I pass a 'SiteCode' value from a parameter file to my main bicep file, I then use that value to restrict my loops to a specific row in an array call 'SiteDetails'. This works just fine

However, I would like pull the values from the array for the specifically selected site row into individual string variables.
I.E. If I select 'UKCH' as the site code, I'd like to make the following variables:

var Code string = 'UKCH'
var VNETRange string = '10.0.1.0/24'
var Region string = 'EMEA'
var DataCenter string = 'NE'
var Location string = 'northeurope'

Is this possible?

[johnlokerse]

@Alastair-Bailey filter() to the rescue! With filter() you can do custom filtering of arrays. In your case, you can filter SiteDetails based on SiteCode and retrieve that one item from the array.

In the Bicep below, you see how to filter the array and set a variable for each value from the object. The first() is used to get the first item from the array. This is because filter() returns an array.

targetScope = 'subscription'

@allowed([
  'UKCH'
  'SGSG'
  'USPT'
])
param SiteCode string = 'SGSG'

param DeploymentDate string = utcNow('y')

param SiteDetails array = [
  { Code: 'UKCH', VNETRange: '10.0.1.0/24', Region: 'EMEA', DataCenter: 'NE', Location: 'northeurope' }
  { Code: 'SGSG', VNETRange: '10.0.2.0/24', Region: 'APAC', DataCenter: 'SEA', Location: 'southeastasia' }
  { Code: 'USPT', VNETRange: '10.0.3.0/24', Region: 'AMER', DataCenter: 'EUS2', Location: 'eastus2' }
]

var filteredDetails = first(filter(SiteDetails, details => details.Code == SiteCode))
var code = filteredDetails.Code
var vnetRange = filteredDetails.VNETRange
var region = filteredDetails.Region
var datacenter = filteredDetails.DataCenter
var loc = filteredDetails.Location

resource ConnectionResourceGroup 'Microsoft.Resources/resourceGroups@2025-04-01' = [
  for Entry in SiteDetails: if (Entry.Code == SiteCode) {
    location: Entry.Location
    name: '${Entry.Code}_${Entry.Region}_${Entry.DataCenter}-Connection'
    tags: {
      Environment: 'IaaS / PaaS'
      Application: 'Site Network / Security'
      LocationValue: Entry.Code
      'Cost Center': 'Site'
      Notification: 'SiteIT.Admin.Notifications.${Entry.Code}@company.com'
      Creation: DeploymentDate
    }
  }
]

Screenshot of the output variables:

[Alastair-Bailey]

This is exactly what I needed. Thank you!