Servantify: misc brig internal api

- `get "/i/users/:uid/contacts" (continue getContactListH)`
- `get "/i/users/activation-code" (continue getActivationCodeH)`
- `get "/i/users/password-reset-code" (continue getPasswordResetCodeH)`

Author: fisx

libs/brig-types/default.nix

@@ -14,7 +14,6 @@
 , imports
 , lib
 , QuickCheck
-, schema-profunctor
 , swagger2
 , tasty
 , tasty-hunit
@@ -39,8 +38,6 @@ mkDerivation {
     containers
     imports
     QuickCheck
-    schema-profunctor
-    swagger2
     text
     time
     tinylog

libs/brig-types/src/Brig/Types/Connection.hs

@@ -1,5 +1,3 @@
-{-# LANGUAGE OverloadedStrings #-}
-
 -- This file is part of the Wire Server implementation.
 --
 -- Copyright (C) 2022 Wire Swiss GmbH <[email protected]>
@@ -32,15 +30,9 @@ import Data.Aeson
 import Data.Id (UserId)
 import Data.Qualified
 import Imports
+import Wire.API.User (UserIds (..))
 import Wire.Arbitrary
 
--- | Response type for endpoints returning lists of users with a specific connection state.
--- E.g. 'getContactList' returns a 'UserIds' containing the list of connections in an
--- 'Accepted' state.
-data UserIds = UserIds
-  {cUsers :: [UserId]}
-  deriving (Eq, Show, Generic)
-
 -- FUTUREWORK: This needs to get Qualified IDs when implementing
 -- Legalhold + Federation, as it's used in the internal
 -- putConnectionInternal / galley->Brig "/i/users/connections-status"
@@ -59,15 +51,3 @@ instance FromJSON UpdateConnectionsInternal
 
 -- | `{"tag":"BlockForMissingLHConsent","contents":["3ae7f23a-bd47-11eb-932d-5fccbbcde454",["3ae7f23a-bd47-11eb-932d-5fccbbcde454"]]}`
 instance ToJSON UpdateConnectionsInternal
-
-----------------------------------------------------------------------------
--- JSON instances
-
-instance FromJSON UserIds where
-  parseJSON = withObject "userids" $ \o ->
-    UserIds <$> o .: "ids"
-
-instance ToJSON UserIds where
-  toJSON (UserIds us) =
-    object
-      ["ids" .= us]

libs/wire-api/src/Wire/API/Routes/Internal/Brig.hs

@@ -39,7 +39,6 @@ where
 
 import Control.Lens ((.~))
 import Data.Aeson (FromJSON, ToJSON)
-import Data.ByteString.Conversion (List)
 import qualified Data.Code as Code
 import Data.CommaSeparatedList
 import Data.Handle (Handle)
@@ -251,6 +250,29 @@ type AccountAPI =
                     Bool
                :> Get '[Servant.JSON] [UserAccount]
            )
+    :<|> Named
+           "iGetUserContacts"
+           ( "users"
+               :> Capture "uid" UserId
+               :> "contacts"
+               :> Get '[Servant.JSON] UserIds
+           )
+    :<|> Named
+           "iGetUserActivationCode"
+           ( "users"
+               :> "activation-code"
+               :> QueryParam' [Optional, Strict] "email" Email
+               :> QueryParam' [Optional, Strict] "phone" Phone
+               :> Get '[Servant.JSON] GetActivationCodeResp
+           )
+    :<|> Named
+           "iGetUserPasswordResetCode"
+           ( "users"
+               :> "password-reset-code"
+               :> QueryParam' [Optional, Strict] "email" Email
+               :> QueryParam' [Optional, Strict] "phone" Phone
+               :> Get '[Servant.JSON] GetPasswordResetCodeResp
+           )
 
 -- | The missing ref is implicit by the capture
 data NewKeyPackageRef = NewKeyPackageRef

libs/wire-api/src/Wire/API/User.hs

@@ -22,6 +22,7 @@
 module Wire.API.User
   ( ListUsersById (..),
     UserIdList (..),
+    UserIds (..),
     QualifiedUserIdList (..),
     LimitedQualifiedUserIdList (..),
     ScimUserInfo (..),
@@ -115,6 +116,10 @@ module Wire.API.User
     -- * List Users
     ListUsersQuery (..),
 
+    -- * misc internal
+    GetActivationCodeResp (..),
+    GetPasswordResetCodeResp (..),
+
     -- * re-exports
     module Wire.API.User.Identity,
     module Wire.API.User.Profile,
@@ -182,9 +187,10 @@ import Wire.API.Provider.Service (ServiceRef)
 import Wire.API.Routes.MultiVerb
 import Wire.API.Team (BindingNewTeam, bindingNewTeamObjectSchema)
 import Wire.API.Team.Role
-import Wire.API.User.Activation (ActivationCode)
+import Wire.API.User.Activation (ActivationCode, ActivationKey)
 import Wire.API.User.Auth (CookieLabel)
 import Wire.API.User.Identity
+import Wire.API.User.Password
 import Wire.API.User.Profile
 import Wire.API.User.RichInfo
 import Wire.Arbitrary (Arbitrary (arbitrary), GenericUniform (..))
@@ -224,6 +230,52 @@ instance ToSchema UserIdList where
         <$> mUsers
           .= field "user_ids" (array schema)
 
+-- | Response type for endpoints returning lists of users with a specific connection state.
+-- E.g. 'getContactList' returns a 'UserIds' containing the list of connections in an
+-- 'Accepted' state.
+--
+-- There really shouldn't be both types `UserIds` and `UserIdList`, but refactoring them
+-- away requires changing the api.
+newtype UserIds = UserIds
+  {cUsers :: [UserId]}
+  deriving (Eq, Show, Generic)
+  deriving newtype (Arbitrary)
+  deriving (FromJSON, ToJSON, S.ToSchema) via Schema UserIds
+
+instance ToSchema UserIds where
+  schema =
+    object "UserIds" $
+      UserIds
+        <$> cUsers
+          .= field "ids" (array schema)
+
+--------------------------------------------------------------------------------
+-- misc internal
+
+newtype GetActivationCodeResp = GetActivationCodeResp {fromGetActivationCodeResp :: (ActivationKey, ActivationCode)}
+  deriving (Eq, Show, Generic)
+  deriving newtype (Arbitrary)
+  deriving (FromJSON, ToJSON, S.ToSchema) via Schema GetActivationCodeResp
+
+instance ToSchema GetActivationCodeResp where
+  schema =
+    object "GetActivationCodeResp" $
+      curry GetActivationCodeResp
+        <$> (fst . fromGetActivationCodeResp) .= field "key" schema
+        <*> (snd . fromGetActivationCodeResp) .= field "code" schema
+
+newtype GetPasswordResetCodeResp = GetPasswordResetCodeResp {fromGetPasswordResetCodeResp :: (PasswordResetKey, PasswordResetCode)}
+  deriving (Eq, Show, Generic)
+  deriving newtype (Arbitrary)
+  deriving (FromJSON, ToJSON, S.ToSchema) via Schema GetPasswordResetCodeResp
+
+instance ToSchema GetPasswordResetCodeResp where
+  schema =
+    object "GetPasswordResetCodeResp" $
+      curry GetPasswordResetCodeResp
+        <$> (fst . fromGetPasswordResetCodeResp) .= field "key" schema
+        <*> (snd . fromGetPasswordResetCodeResp) .= field "code" schema
+
 --------------------------------------------------------------------------------
 -- QualifiedUserIdList
 

services/brig/src/Brig/API.hs

@@ -38,9 +38,7 @@ sitemap ::
   ( Member BlacklistPhonePrefixStore r,
     Member BlacklistStore r,
     Member GalleyProvider r,
-    Member CodeStore r,
     Member (Concurrency 'Unsafe) r,
-    Member PasswordResetStore r,
     Member (UserPendingActivationStore p) r
   ) =>
   Routes () (Handler r) ()

services/brig/src/Brig/API/Internal.hs

@@ -62,7 +62,6 @@ import qualified Brig.User.EJPD
 import qualified Brig.User.Search.Index as Index
 import Control.Error hiding (bool)
 import Control.Lens (view)
-import Data.Aeson hiding (json)
 import Data.ByteString.Conversion
 import qualified Data.ByteString.Conversion as List
 import Data.CommaSeparatedList
@@ -72,6 +71,7 @@ import qualified Data.Map.Strict as Map
 import Data.Qualified
 import qualified Data.Set as Set
 import Imports hiding (cs, head)
+import qualified Imports
 import Network.HTTP.Types.Status
 import Network.Wai (Response)
 import Network.Wai.Predicate hiding (result, setStatus)
@@ -98,7 +98,6 @@ import qualified Wire.API.Team.Feature as ApiFt
 import Wire.API.User
 import Wire.API.User.Activation
 import Wire.API.User.Client
-import Wire.API.User.Password
 import Wire.API.User.RichInfo
 
 ---------------------------------------------------------------------------
@@ -107,6 +106,8 @@ import Wire.API.User.RichInfo
 servantSitemap ::
   forall r p.
   ( Member BlacklistStore r,
+    Member CodeStore r,
+    Member PasswordResetStore r,
     Member GalleyProvider r,
     Member (UserPendingActivationStore p) r
   ) =>
@@ -153,6 +154,8 @@ mlsAPI =
 
 accountAPI ::
   ( Member BlacklistStore r,
+    Member CodeStore r,
+    Member PasswordResetStore r,
     Member GalleyProvider r,
     Member (UserPendingActivationStore p) r
   ) =>
@@ -166,6 +169,9 @@ accountAPI =
     :<|> Named @"iGetUserStatus" getAccountStatusH
     :<|> Named @"iGetUsersByEmailOrPhone" listAccountsByIdentityH
     :<|> Named @"iGetUsersByIdsOrHandles" listActivatedAccountsH
+    :<|> Named @"iGetUserContacts" getContactListH
+    :<|> Named @"iGetUserActivationCode" getActivationCodeH
+    :<|> Named @"iGetUserPasswordResetCode" getPasswordResetCodeH
 
 teamsAPI :: ServerT BrigIRoutes.TeamsAPI (Handler r)
 teamsAPI = Named @"updateSearchVisibilityInbound" Index.updateSearchVisibilityInbound
@@ -293,9 +299,7 @@ internalSearchIndexAPI =
 -- Sitemap (wai-route)
 
 sitemap ::
-  ( Member CodeStore r,
-    Member PasswordResetStore r,
-    Member BlacklistStore r,
+  ( Member BlacklistStore r,
     Member BlacklistPhonePrefixStore r,
     Member GalleyProvider r,
     Member (UserPendingActivationStore p) r
@@ -306,18 +310,6 @@ sitemap = unsafeCallsFed @'Brig @"on-user-deleted-connections" $ do
     accept "application" "json"
       .&. jsonRequest @UpdateConnectionsInternal
 
-  get "/i/users/:uid/contacts" (continue getContactListH) $
-    accept "application" "json"
-      .&. capture "uid"
-
-  get "/i/users/activation-code" (continue getActivationCodeH) $
-    accept "application" "json"
-      .&. (param "email" ||| param "phone")
-
-  get "/i/users/password-reset-code" (continue getPasswordResetCodeH) $
-    accept "application" "json"
-      .&. (param "email" ||| param "phone")
-
   -- This endpoint can lead to the following events being sent:
   -- - UserIdentityRemoved event to target user
   post "/i/users/revoke-identity" (continue revokeIdentityH) $
@@ -579,42 +571,35 @@ listAccountsByIdentityH mbEmail mbPhone (fromMaybe False -> includePendingInvita
     u2 <- maybe (pure []) (\phone -> API.lookupAccountsByIdentity (Right phone) includePendingInvitations) mbPhone
     pure $ u1 <> u2
 
-getActivationCodeH :: JSON ::: Either Email Phone -> (Handler r) Response
-getActivationCodeH (_ ::: emailOrPhone) = do
-  json <$> getActivationCode emailOrPhone
+getActivationCodeH :: Maybe Email -> Maybe Phone -> (Handler r) GetActivationCodeResp
+getActivationCodeH (Just email) Nothing = getActivationCode (Left email)
+getActivationCodeH Nothing (Just phone) = getActivationCode (Right phone)
+getActivationCodeH bade badp = throwStd (badRequest ("need exactly one of email, phone: " <> Imports.cs (show (bade, badp))))
 
 getActivationCode :: Either Email Phone -> (Handler r) GetActivationCodeResp
 getActivationCode emailOrPhone = do
   apair <- lift . wrapClient $ API.lookupActivationCode emailOrPhone
   maybe (throwStd activationKeyNotFound) (pure . GetActivationCodeResp) apair
 
-newtype GetActivationCodeResp = GetActivationCodeResp (ActivationKey, ActivationCode)
-
-instance ToJSON GetActivationCodeResp where
-  toJSON (GetActivationCodeResp (k, c)) = object ["key" .= k, "code" .= c]
-
 getPasswordResetCodeH ::
   ( Member CodeStore r,
     Member PasswordResetStore r
   ) =>
-  JSON ::: Either Email Phone ->
-  (Handler r) Response
-getPasswordResetCodeH (_ ::: emailOrPhone) = do
-  maybe (throwStd (errorToWai @'E.InvalidPasswordResetKey)) (pure . json) =<< lift (getPasswordResetCode emailOrPhone)
+  Maybe Email ->
+  Maybe Phone ->
+  (Handler r) GetPasswordResetCodeResp
+getPasswordResetCodeH (Just email) Nothing = getPasswordResetCode (Left email)
+getPasswordResetCodeH Nothing (Just phone) = getPasswordResetCode (Right phone)
+getPasswordResetCodeH bade badp = throwStd (badRequest ("need exactly one of email, phone: " <> Imports.cs (show (bade, badp))))
 
 getPasswordResetCode ::
   ( Member CodeStore r,
     Member PasswordResetStore r
   ) =>
   Either Email Phone ->
-  (AppT r) (Maybe GetPasswordResetCodeResp)
+  (Handler r) GetPasswordResetCodeResp
 getPasswordResetCode emailOrPhone =
-  GetPasswordResetCodeResp <$$> API.lookupPasswordResetCode emailOrPhone
-
-newtype GetPasswordResetCodeResp = GetPasswordResetCodeResp (PasswordResetKey, PasswordResetCode)
-
-instance ToJSON GetPasswordResetCodeResp where
-  toJSON (GetPasswordResetCodeResp (k, c)) = object ["key" .= k, "code" .= c]
+  (GetPasswordResetCodeResp <$$> lift (API.lookupPasswordResetCode emailOrPhone)) >>= maybe (throwStd (errorToWai @'E.InvalidPasswordResetKey)) pure
 
 changeAccountStatusH :: UserId -> AccountStatusUpdate -> (Handler r) NoContent
 changeAccountStatusH usr (suStatus -> status) = do
@@ -798,7 +783,5 @@ checkHandleInternalH =
     API.CheckHandleFound -> pure $ setStatus status200 empty
     API.CheckHandleNotFound -> pure $ setStatus status404 empty
 
-getContactListH :: JSON ::: UserId -> (Handler r) Response
-getContactListH (_ ::: uid) = do
-  contacts <- lift . wrapClient $ API.lookupContactList uid
-  pure $ json $ UserIds contacts
+getContactListH :: UserId -> (Handler r) UserIds
+getContactListH uid = lift . wrapClient $ UserIds <$> API.lookupContactList uid

services/brig/src/Brig/Data/Activation.hs

@@ -18,8 +18,6 @@
 -- | Activation of 'Email' addresses and 'Phone' numbers.
 module Brig.Data.Activation
   ( Activation (..),
-    ActivationKey (..),
-    ActivationCode (..),
     ActivationEvent (..),
     ActivationError (..),
     activationErrorToRegisterError,

services/galley/src/Galley/Intra/User.hs

@@ -37,7 +37,7 @@ where
 
 import Bilge hiding (getHeader, options, statusCode)
 import Bilge.RPC
-import Brig.Types.Connection (UpdateConnectionsInternal, cUsers)
+import Brig.Types.Connection (UpdateConnectionsInternal)
 import qualified Brig.Types.Intra as Brig
 import Control.Error hiding (bool, isRight)
 import Control.Lens (view, (^.))