Merge pull request #1 from i4ki/i4k-create-project

feat: add variables generation module.

Author: i4ki

.github/workflows/ci.yml

@@ -0,0 +1,23 @@
+name: test modules
+
+on:
+  push:
+
+jobs:
+  test:
+    runs-on: ubuntu-latest
+    env:
+      GITHUB_TOKEN: ${{ github.token }}
+
+    steps:
+      - name: Checkout
+        uses: actions/checkout@v4
+        with:
+          ref: ${{ github.head_ref }}
+          fetch-depth: 0
+
+      - name: Install terramate
+        uses: terramate-io/terramate-action@v1
+
+      - name: Run generate tests
+        run: terramate generate

README.md

@@ -0,0 +1,65 @@
+# Terramate Modules
+
+## Install
+
+Clone this repo into the `/modules` folder of your Terramate project.
+
+```bash
+git clone [email protected]:i4ki/terramate-modules.git ./modules/terramate-modules
+```
+
+Add a `.tmskip` file into the `modules/terramate-modules/tests` directory.
+This is needed because this project comes with test stacks, otherwise they will
+show up in your `terramate list` results.
+
+```bash
+touch ./modules/terramate-modules/tests/.tmskip
+```
+
+and then import the specific module and configure it accordingly to its documentation.
+
+See usage examples below:
+
+## Generate configurable variable blocks
+
+Sometimes you have a highly configurable setup and you would like to generate
+variable blocks dynamically, depending on if some flags are enabled or not.
+
+```hcl
+import {
+  source = "/modules/terraform-modules/generate/terraform/variables/variables.tm"
+}
+
+globals "modules" "generate" "terraform" "variables" {
+  entries = [
+    {
+      # only declaring name is enough.
+      name = "empty_var"
+    },
+    # basic string variable
+    {
+      name      = "my_var"
+      type      = "string"
+      default   = "hello"
+      sensitive = false
+    },
+    
+    # line below only generate if feature abc is defined.
+    tm_try(global.feature_abc.variable, null)
+  ]
+}
+```
+
+which generates:
+```
+// TERRAMATE: GENERATED AUTOMATICALLY DO NOT EDIT
+
+variable "empty_var" {
+}
+variable "my_var" {
+  default   = "hello"
+  sensitive = false
+  type      = string
+}
+```
+

generate/terraform/variables/variables.tm

@@ -0,0 +1,28 @@
+# Generate the variables block.
+#
+# Example configuration:
+globals "modules" "generate" "terraform" "variables" {
+  entries = [
+    # {name = "some_var_name", type = "list", default = ["test"]}
+  ]
+}
+
+# Generate variable blocks based on a globals configuration.
+generate_hcl "_variables.tf" {
+  content {
+    tm_dynamic "variable" {
+      # Note: It's a feature that `null` entries can be present so it's easier to disable
+      # entries. Eg.: entries = [tm_try(global.featA, null), tm_try(global.festB, null), ...]
+      for_each = [for v in global.modules.generate.terraform.variables.entries : v if v != null]
+      iterator = var
+      labels   = [var.value.name]
+
+      attributes = { for k, v in {
+        default   = tm_try(var.value.default, null)
+        type      = tm_try(tm_hcl_expression(var.value.type), null)
+        sensitive = tm_try(var.value.sensitive, null)
+        } : k => v if v != null
+      }
+    }
+  }
+}

tests/generate/variables/strings/_variables.tf

@@ -0,0 +1,20 @@
+// TERRAMATE: GENERATED AUTOMATICALLY DO NOT EDIT
+
+variable "empty_var" {
+}
+variable "my_var" {
+  default   = "hello"
+  sensitive = false
+  type      = string
+}
+variable "my_object" {
+  default = {
+    number = 1
+    str    = "terramate"
+  }
+  sensitive = true
+  type = object({
+    number = number
+    str    = string
+  })
+}

tests/generate/variables/strings/stack.tm.hcl

@@ -0,0 +1,5 @@
+stack {
+  name        = "strings"
+  description = "strings"
+  id          = "40baaeaa-feea-405f-91c0-9424c060fe89"
+}

tests/generate/variables/strings/tests.tm

@@ -0,0 +1,79 @@
+# Test basic string variables
+
+import {
+  source = "/generate/terraform/variables/variables.tm"
+}
+
+globals {
+  testcases = [
+    {
+      # only declaring name is enough.
+      config = {
+        name = "empty_var"
+      },
+      expected = <<-EOF
+        variable "empty_var" {
+        }
+      EOF
+    },
+    {
+      # basic string variable
+      config = {
+        name      = "my_var"
+        type      = "string"
+        default   = "hello"
+        sensitive = false
+      },
+      expected = <<-EOF
+        variable "my_var" {
+          default   = "hello"
+          sensitive = false
+          type      = string
+        }
+      EOF
+    },
+    {
+      # basic object variable
+      config = {
+        name = "my_object"
+        type = "object({number = number, str = string})"
+        default = {
+          number = 1
+          str    = "terramate"
+        }
+        sensitive = true
+      },
+      expected = <<-EOF
+        variable "my_object" {
+          default = {
+            number = 1
+            str    = "terramate"
+          }
+          sensitive = true
+          type = object({
+            number = number
+            str    = string
+          })
+        }
+      EOF
+    },
+    {
+      # null is ignored in the entries list.
+      config   = null,
+      expected = null,
+    }
+  ]
+}
+
+globals "modules" "generate" "terraform" "variables" {
+  entries = [for k, v in global.testcases : v.config]
+}
+
+assert {
+  assertion = tm_alltrue(
+    [for v in global.testcases :
+    v.expected == null ? true : tm_strcontains(tm_try(tm_file("_variables.tf"), ""), v.expected)]
+  )
+  message = "test failed"
+}
+