ci: job to build QT6 Image and android APK

- https://ci.status.im/job/status-desktop/job/systems/job/QT/ is set up to build our own QT6 Image from source. Running this would be a manual job and we would only need to do this when we'd have to change the version of QT.

- https://ci.status.im/job/status-desktop/job/prs/job/android/job/arm64/job/package/ is set up to build Android APK for each PR.

fixes: #18468

Author: siddarthkay

ci/Jenkinsfile.android

@@ -0,0 +1,100 @@
+#!/usr/bin/env groovy
+library '[email protected]'
+
+/* Options section can't access functions in objects. */
+def isPRBuild = utils.isPRBuild()
+def isNightlyBuild = utils.isNightlyBuild()
+
+pipeline {
+  agent {
+    /* Image with Ubuntu 22.04, QT 6.9.0, Android SDK/NDK, Go, and Nim */
+    docker {
+      label 'linux'
+      image 'statusteam/nim-status-client-build:1.0.3-qt6.9.0-android'
+      alwaysPull true
+    }
+  }
+
+  parameters {
+    booleanParam(
+      name: 'RELEASE',
+      description: 'Decides whether release credentials are used.',
+      defaultValue: params.RELEASE ?: false
+    )
+  }
+
+  options {
+    timestamps()
+    /* Prevent Jenkins jobs from running forever */
+    timeout(time: 45, unit: 'MINUTES')
+    /* manage how many builds we keep */
+    buildDiscarder(logRotator(
+      numToKeepStr: '10',
+      daysToKeepStr: '30',
+      artifactNumToKeepStr: '3',
+    ))
+    /* Allows combined build to copy */
+    copyArtifactPermission('/status-desktop/*')
+    /* Abort old PR builds. */
+    disableConcurrentBuilds(abortPrevious: isPRBuild)
+    disableRestartFromStage()
+  }
+
+  environment {
+    USE_SYSTEM_NIM = "1"
+    GOCACHE = "${env.WORKSPACE_TMP}/go-cache"
+    GOMODCACHE = "${env.WORKSPACE_TMP}/go-mod-cache"
+    GOTMPDIR = "${env.WORKSPACE_TMP}"
+    STATUS_APK_ARTIFACT = "pkg/Status-tablet-${BUILD_NUMBER}.apk"
+    PLATFORM = "android/arm64"
+    QT_ANDROID_PATH = "/opt/qt/6.9.0/android_arm64_v8a"
+    STATUS_APK = "${WORKSPACE}/mobile/bin/android/qt6/default/Status-tablet.apk"
+  }
+
+  stages {
+
+    stage('Build Android APK') {
+      steps {
+        sh """
+          make mobile-clean
+          make -j${utils.getProcCount()} mobile-build V=3 USE_SYSTEM_NIM=1
+        """
+      }
+    }
+
+    stage('Package APK') {
+      steps {
+        sh """
+          mkdir -p pkg
+          cp '${env.STATUS_APK}' '${env.STATUS_APK_ARTIFACT}'
+          ls -la '${env.STATUS_APK_ARTIFACT}'
+        """
+      }
+    }
+
+    stage('Parallel Upload') {
+      parallel {
+        stage('Upload') {
+          steps {
+            script {
+              env.PKG_URL = s5cmd.upload(env.STATUS_APK_ARTIFACT)
+              jenkins.setBuildDesc(APK: env.PKG_URL)
+            }
+          }
+        }
+        stage('Archive') {
+          steps {
+            archiveArtifacts env.STATUS_APK_ARTIFACT
+          }
+        }
+      }
+    }
+  }
+
+  post {
+      success { script { github.notifyPR(true) } }
+      failure { script { github.notifyPR(false) } }
+      cleanup { sh './scripts/clean-git.sh' }
+  }
+}
+

ci/Jenkinsfile.qt-build

@@ -0,0 +1,103 @@
+#!/usr/bin/env groovy
+library '[email protected]'
+
+pipeline {
+  agent {
+    label 'linux && x86_64 && qt-builder'
+  }
+
+  options {
+    buildDiscarder(logRotator(numToKeepStr: '20'))
+    timestamps()
+    timeout(time: 12, unit: 'HOURS')
+  }
+
+  parameters {
+    string(
+      name: 'QT_VERSION',
+      defaultValue: '6.9.0',
+      description: 'Qt version to build'
+    )
+    string(
+      name: 'DOCKER_TAG',
+      defaultValue: '1.0.3-qt6.9.0-android',
+      description: 'Docker image tag for the final image'
+    )
+    booleanParam(
+      name: 'PUSH_TO_DOCKERHUB',
+      defaultValue: true,
+      description: 'Push the final image to DockerHub'
+    )
+  }
+
+  environment {
+    DOCKER_REGISTRY = 'statusteam'
+    DOCKER_IMAGE_BASE = 'nim-status-client-build'
+    MOBILE_BUILD_DIR = "${WORKSPACE}/mobile/docker"
+  }
+
+  stages {
+    stage('Build Docker Images') {
+      steps {
+        script {
+          dir("${MOBILE_BUILD_DIR}") {
+
+            def image = docker.build(
+              "${DOCKER_REGISTRY}/${DOCKER_IMAGE_BASE}:${params.DOCKER_TAG}",
+              "--build-arg QTVER=${params.QT_VERSION} " +
+              "--build-arg TARGETARCH=amd64 " +
+              "--build-arg JAVA_VERSION=17 " +
+              "--build-arg ANDROID_API_LEVEL=35 " +
+              "--build-arg ANDROID_NDK_VERSION=27.2.12479018 " +
+              "--build-arg GOLANG_VERSION=1.23.10 " +
+              "--build-arg NIM_VERSION=2.0.12 " +
+              "--build-arg NIX_VERSION=2.24.11 " +
+              "--target mobile-build ."
+            )
+            
+            env.BUILT_IMAGE = "${DOCKER_REGISTRY}/${DOCKER_IMAGE_BASE}:${params.DOCKER_TAG}"
+          }
+        }
+      }
+    }
+
+    stage('Test Images') {
+      parallel {
+        stage('Test Mobile Build Image') {
+          steps {
+            script {
+              def testImage = "${DOCKER_REGISTRY}/${DOCKER_IMAGE_BASE}:${params.DOCKER_TAG}"
+              docker.image(testImage).inside('--entrypoint=""') {
+                sh "qmake --version"
+                sh "nim --version"
+                sh "go version"
+                sh "protoc --version"
+                sh "java -version"
+                sh "ls -la /opt/qt/${params.QT_VERSION}/"
+              }
+            }
+          }
+        }
+
+      }
+    }
+
+    stage('Push to DockerHub') {
+      when {
+        expression { params.PUSH_TO_DOCKERHUB == true }
+      }
+      steps {
+        script {
+          def image = docker.image(env.BUILT_IMAGE)
+          image.push()
+        }
+      }
+    }
+  }
+
+  post {
+    always { cleanWs() }
+    success { script { github.notifyPR(true) } }
+    failure { script { github.notifyPR(false) } }
+  }
+}