Use SDL2 :borderless flag to simulate emacs-plus's --no-title-bar appearance

[li-yiyang]

In lem-sdl2::create-display function, add :borderless flag in sdl2:with-window could create the Lem window without macOS's titlebar, which is much more nice looking.

the code is be like:

(defun create-display (function)
  (lem-sdl2/wm:set-x11-wm-class)
  (sdl2:with-init (:video)
    (sdl2-ttf:init)
    (sdl2-image:init '(:png))
    (unwind-protect
         (let* ((font-config (make-font-config))
                (font (open-font font-config))
                (char-width (font-char-width font))
                (char-height (font-char-height font))
                (window-width (* +display-width+ char-width))
                (window-height (* +display-height+ char-height)))
           (sdl2:with-window (window :title "Lem"
                                     :w window-width
                                     :h window-height
                                     ;; :flags '(:shown :resizable :allow-highdpi)
                                     :flags '(:shown :resizable :allow-highdpi
                                              #+darwin :metal 
                                              :borderless))
             (init-application-icon window)
             (sdl2:with-renderer (renderer window :index -1 :flags '(:accelerated))
               (let* ((renderer-size (multiple-value-list
                                               (sdl2:get-renderer-output-size renderer)))
                      (renderer-width (first renderer-size))
                      (renderer-height (second renderer-size))
                      (scale-x (/ renderer-width window-width))
                      (scale-y (/ renderer-height window-height))
                      (texture (lem-sdl2/utils:create-texture renderer
                                                              (* scale-x window-width)
                                                              (* scale-y window-height)))
                      (display (make-instance 'display:display
                                              :font-config font-config
                                              :font font
                                              :renderer renderer
                                              :window window
                                              :texture texture
                                              :char-width (font-char-width font)
                                              :char-height (font-char-height font)
                                              :scale (list scale-x scale-y))))
                 (setf (display:current-display) display)
                 (display:adapt-high-dpi-font-size display)
                 (sdl2:start-text-input)
                 (funcall function)
                 (event-loop display)))))
      (sdl2-ttf:quit)
      (sdl2-image:quit))))

[li-yiyang]

This PR (#1863) should introduce toggle window borderless feature dynamically (not sure if it's necessary).

Or the following path is ready to use:

;;;; Toggle Display Borderless
(in-package :lem-sdl2)

(defgeneric lem-if::display-borderless-p (implementation)
  (:documentation
   "Return `t' if FRAME is borderless, `nil' otherwise. 
Default IMPLEMENTATION should return `t' as fallback. ")
  (:method (implementation) t)
  (:method ((implementation sdl2))
    (with-debug ("display-borderless-p")
      (display:with-display (display)
        (not (null (member :borderless (sdl2:get-window-flags (display:display-window display)))))))))

(defmethod (setf lem-if::display-borderless-p) (boolean implementation)
  (declare (ignore boolean implementation)))

(defmethod (setf lem-if::display-borderless-p) (boolean (implementation sdl2))
  (declare (ignore implementation))
  (with-debug ("(setf lem-if::display-borderless-p)")
    (sdl2:in-main-thread ()
      (display:with-display (display)
        (sdl2-ffi.functions:sdl-set-window-bordered (display:display-window display) 
                                                    (if boolean 0 1))))))

(in-package :lem-core)

(defun lem-core::display-borderless-p ()
  "Get/Set current display if borderless. 
Return `t' for borderless (no-titlebar), `nil' for otherwise. "
  (lem-if::display-borderless-p (implementation)))

(defun (setf lem-core::display-borderless-p) (boolean)
  (setf (lem-if::display-borderless-p (implementation)) boolean))

(define-command toggle-frame-borderless () ()
  "Toggles frame borderless. "
  (setf (display-borderless-p) (not (display-borderless-p))))

[vindarel]

cool!