Add support for plugins

titanous · titanous · commit c3836618afd2 · 2023-01-12T16:31:36.000Z
diff --git a/examples/plugins/BUILD.bazel b/examples/plugins/BUILD.bazel
@@ -0,0 +1,54 @@
+load("@aspect_rules_swc//swc:defs.bzl", "swc", "swc_plugin")
+
+swc_plugin(
+    name = "npm_plugin",
+    src = "//examples/plugins/plugin-transform-imports:package",
+    config = {
+        "lodash": {
+            "transform": "lodash/{{member}}",
+        },
+    },
+)
+
+swc_plugin(
+    name = "file_plugin",
+    src = "//examples/plugins/plugin-transform-imports:swc_plugin_transform_imports.wasm",
+    config = json.encode({
+        "lodash2": {
+            "transform": "lodash/test/{{member}}",
+        },
+    }),
+)
+
+swc(
+    name = "simple",
+    out_dir = "simple",
+    plugins = [
+        ":npm_plugin",
+        ":file_plugin",
+    ],
+)
+
+swc(
+    name = "rcdict",
+    out_dir = "rcdict",
+    plugins = [
+        ":npm_plugin",
+        ":file_plugin",
+    ],
+    swcrc = {
+        "jsc": {
+            "target": "es5",
+        },
+    },
+)
+
+swc(
+    name = "rc",
+    out_dir = "rc",
+    plugins = [
+        ":npm_plugin",
+        ":file_plugin",
+    ],
+    swcrc = "minify.swcrc",
+)
diff --git a/examples/plugins/in.ts b/examples/plugins/in.ts
@@ -0,0 +1,2 @@
+import { map } from "lodash";
+import { sort } from "lodash2";
diff --git a/examples/plugins/minify.swcrc b/examples/plugins/minify.swcrc
@@ -0,0 +1,10 @@
+{
+    "jsc": {
+        "minify": true,
+        "experimental": {
+            "plugins": [
+                "__PLUGINS__"
+            ]
+        }
+    }
+}
diff --git a/examples/plugins/plugin-transform-imports/BUILD.bazel b/examples/plugins/plugin-transform-imports/BUILD.bazel
@@ -0,0 +1,15 @@
+load("@aspect_rules_js//npm:defs.bzl", "npm_package")
+
+exports_files(
+    ["swc_plugin_transform_imports.wasm"],
+    visibility = ["//examples/plugins:__pkg__"],
+)
+
+npm_package(
+    name = "package",
+    srcs = [
+        "package.json",
+        "swc_plugin_transform_imports.wasm",
+    ],
+    visibility = ["//examples/plugins:__pkg__"],
+)
diff --git a/examples/plugins/plugin-transform-imports/package.json b/examples/plugins/plugin-transform-imports/package.json
@@ -0,0 +1,5 @@
+{
+  "name": "@swc/plugin-transform-imports",
+  "version": "1.5.35",
+  "index": "swc_plugin_transform_imports.wasm"
+}
diff --git a/examples/plugins/plugin-transform-imports/swc_plugin_transform_imports.wasm b/examples/plugins/plugin-transform-imports/swc_plugin_transform_imports.wasm
diff --git a/swc/BUILD.bazel b/swc/BUILD.bazel
@@ -41,6 +41,7 @@ bzl_library(
     visibility = ["//visibility:public"],
     deps = [
         "//swc/private:swc",
+        "//swc/private:swc_plugin",
         "@bazel_skylib//lib:types",
         "@bazel_skylib//rules:write_file",
     ],
@@ -51,3 +52,12 @@ bzl_library(
     srcs = ["toolchain.bzl"],
     visibility = ["//visibility:public"],
 )
+
+bzl_library(
+    name = "providers",
+    srcs = ["providers.bzl"],
+    visibility = ["//visibility:public"],
+    deps = [
+        "//swc/private:swc_plugin_config_info",
+    ],
+)
diff --git a/swc/defs.bzl b/swc/defs.bzl
@@ -12,6 +12,7 @@ swc(name = "compile")
 """
 
 load("//swc/private:swc.bzl", _swc_lib = "swc")
+load("//swc/private:swc_plugin.bzl", _swc_plugin_lib = "swc_plugin")
 load("@aspect_bazel_lib//lib:utils.bzl", "file_exists", "to_label")
 load("@bazel_skylib//lib:types.bzl", "types")
 load("@bazel_skylib//rules:write_file.bzl", "write_file")
@@ -30,7 +31,7 @@ for example to set your own output labels for `js_outs`.
     toolchains = _swc_lib.toolchains,
 )
 
-def swc(name, srcs = None, args = [], data = [], output_dir = False, swcrc = None, source_maps = False, out_dir = None, root_dir = None, **kwargs):
+def swc(name, srcs = None, args = [], data = [], plugins = [], output_dir = False, swcrc = None, source_maps = False, out_dir = None, root_dir = None, **kwargs):
     """Execute the SWC compiler
 
     Args:
@@ -59,6 +60,8 @@ def swc(name, srcs = None, args = [], data = [], output_dir = False, swcrc = Non
             these don't accidentally diverge.
             See an example in `examples/paths/BUILD.bazel`.
 
+        plugins: Array of plugin labels created with `swc_plugin`.
+
         out_dir: The base directory for output files relative to the output directory for this package
 
         root_dir: A subdirectory under the input package which should be considered the root directory of all the input files
@@ -75,6 +78,10 @@ def swc(name, srcs = None, args = [], data = [], output_dir = False, swcrc = Non
             swcrc = ".swcrc"
     elif type(swcrc) == type(dict()):
         swcrc.setdefault("sourceMaps", source_maps)
+        if plugins:
+            swcrc.setdefault("jsc", {})
+            swcrc["jsc"].setdefault("experimental", {})
+            swcrc["jsc"]["experimental"]["plugins"] = ["__PLUGINS__"]
         rcfile = "{}_swcrc.json".format(name)
         write_file(
             name = "_gen_swcrc_" + name,
@@ -103,6 +110,7 @@ def swc(name, srcs = None, args = [], data = [], output_dir = False, swcrc = Non
     swc_compile(
         name = name,
         srcs = srcs,
+        plugins = plugins,
         js_outs = js_outs,
         map_outs = map_outs,
         output_dir = output_dir,
@@ -114,3 +122,33 @@ def swc(name, srcs = None, args = [], data = [], output_dir = False, swcrc = Non
         root_dir = root_dir,
         **kwargs
     )
+
+_swc_plugin = rule(
+    doc = "Configure an SWC plugin",
+    implementation = _swc_plugin_lib.implementation,
+    attrs = _swc_plugin_lib.attrs,
+    provides = _swc_plugin_lib.provides,
+)
+
+def swc_plugin(name, src = None, config = None, **kwargs):
+    """Configure an SWC plugin
+
+    Args:
+        name: A name for this target
+
+        src: Label for the plugin, either a directory containing a package.json pointing at a wasm file
+            as the main entrypoint, or a wasm file.
+
+        config: Configuration for the plugin, either a dict or a string containing a serialized JSON object.
+
+        **kwargs: additional keyword arguments passed through to underlying rule, eg. `visibility`, `tags`
+    """
+    if type(config) == type(dict()):
+        config = json.encode(config)
+
+    _swc_plugin(
+        name = name,
+        src = src,
+        config = config,
+        **kwargs
+    )
diff --git a/swc/private/BUILD.bazel b/swc/private/BUILD.bazel
@@ -1,5 +1,7 @@
 load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
 
+exports_files(["plugins.swcrc"])
+
 bzl_library(
     name = "toolchains_repo",
     srcs = ["toolchains_repo.bzl"],
@@ -12,11 +14,27 @@ bzl_library(
     visibility = ["//swc:__subpackages__"],
 )
 
+bzl_library(
+    name = "swc_plugin_config_info",
+    srcs = ["swc_plugin_config_info.bzl"],
+    visibility = ["//swc:__subpackages__"],
+)
+
+bzl_library(
+    name = "swc_plugin",
+    srcs = ["swc_plugin.bzl"],
+    visibility = ["//swc:__subpackages__"],
+    deps = [
+        ":swc_plugin_config_info",
+    ],
+)
+
 bzl_library(
     name = "swc",
     srcs = ["swc.bzl"],
     visibility = ["//swc:__subpackages__"],
     deps = [
+        ":swc_plugin_config_info",
         "@aspect_bazel_lib//lib:platform_utils",
         "@aspect_rules_js//js:libs",
         "@aspect_rules_js//js:providers",
diff --git a/swc/private/plugins.swcrc b/swc/private/plugins.swcrc
@@ -0,0 +1,9 @@
+{
+    "jsc": {
+        "experimental": {
+            "plugins": [
+                "__PLUGINS__"
+            ]
+        }
+    }
+}
diff --git a/swc/private/swc.bzl b/swc/private/swc.bzl
@@ -1,9 +1,11 @@
 "Internal implementation details"
 
 load("@aspect_bazel_lib//lib:platform_utils.bzl", "platform_utils")
+load("@aspect_bazel_lib//lib:paths.bzl", "relative_file")
 load("@aspect_rules_js//js:libs.bzl", "js_lib_helpers")
 load("@aspect_rules_js//js:providers.bzl", "js_info")
 load("@bazel_skylib//lib:paths.bzl", "paths")
+load(":swc_plugin_config_info.bzl", "SwcPluginConfigInfo")
 
 _attrs = {
     "srcs": attr.label_list(
@@ -34,12 +36,21 @@ _attrs = {
         doc = "label of a configuration file for swc, see https://swc.rs/docs/configuration/swcrc",
         allow_single_file = True,
     ),
+    "plugins": attr.label_list(
+        doc = "swc compilation plugins, created with swc_plugin rule",
+        providers = [[DefaultInfo, SwcPluginConfigInfo]],
+    ),
     "out_dir": attr.string(
         doc = "base directory for output files",
     ),
     "root_dir": attr.string(
         doc = "a subdirectory under the input package which should be consider the root directory of all the input files",
     ),
+    "_swcrc_plugins_template": attr.label(
+        doc = "swcrc used when plugins are specified with no swcrc",
+        default = "@aspect_rules_swc//swc/private:plugins.swcrc",
+        allow_single_file = True,
+    ),
 }
 
 _outputs = {
@@ -175,6 +186,26 @@ def _impl(ctx):
     args.add_all(ctx.attr.args)
     args.add_all(["--source-maps", ctx.attr.source_maps])
 
+    swcrc = ctx.file.swcrc
+    if ctx.attr.plugins:
+        swcrc_template = swcrc
+        if not swcrc_template:
+            swcrc_template = ctx.file._swcrc_plugins_template
+
+        swcrc = ctx.actions.declare_file("{}_plugins_swcrc.json".format(ctx.label.name))
+
+        plugins = []
+        for p in ctx.attr.plugins:
+            plugins.append("[" + json.encode("./" + relative_file(p[DefaultInfo].files.to_list()[0].path, swcrc.path)) + "," + p[SwcPluginConfigInfo].config + "]")
+
+        ctx.actions.expand_template(
+            template = swcrc_template,
+            output = swcrc,
+            substitutions = {
+                '"__PLUGINS__"': ",".join(plugins),
+            },
+        )
+
     if ctx.attr.output_dir:
         if len(ctx.attr.srcs) != 1:
             fail("Under output_dir, there must be a single entry in srcs")
@@ -192,12 +223,13 @@ def _impl(ctx):
         ])
 
         src_args = ctx.actions.args()
-        if ctx.attr.swcrc:
+        if swcrc:
             src_args.add_all([
                 "--config-file",
-                ctx.file.swcrc.path,
+                swcrc.path,
             ])
-            inputs.append(ctx.file.swcrc)
+            inputs.append(swcrc)
+            inputs.extend(ctx.files.plugins)
 
         _swc_action(
             ctx,
@@ -238,12 +270,13 @@ def _impl(ctx):
             inputs = [src]
             inputs.extend(ctx.toolchains["@aspect_rules_swc//swc:toolchain_type"].swcinfo.tool_files)
 
-            if ctx.attr.swcrc:
+            if swcrc:
                 src_args.add_all([
                     "--config-file",
-                    ctx.file.swcrc.path,
+                    swcrc.path,
                 ])
-                inputs.append(ctx.file.swcrc)
+                inputs.append(swcrc)
+                inputs.extend(ctx.files.plugins)
 
             src_args.add_all([
                 "--out-file",
diff --git a/swc/private/swc_plugin.bzl b/swc/private/swc_plugin.bzl
@@ -0,0 +1,33 @@
+"Internal implementation details"
+
+load(":swc_plugin_config_info.bzl", "SwcPluginConfigInfo")
+
+_attrs = {
+    "src": attr.label(
+        doc = "label for the plugin, either a directory containing a package.json pointing at a wasm file as the main entrypoint, or a wasm file",
+        providers = [DefaultInfo],
+        mandatory = True,
+        allow_single_file = True,
+    ),
+    "config": attr.string(
+        doc = "configuration object for the plugin, serialized JSON",
+        default = "{}",
+    ),
+}
+
+def _impl(ctx):
+    return [
+        DefaultInfo(
+            files = ctx.attr.src[DefaultInfo].files,
+        ),
+        SwcPluginConfigInfo(
+            label = ctx.label,
+            config = ctx.attr.config,
+        ),
+    ]
+
+swc_plugin = struct(
+    attrs = _attrs,
+    implementation = _impl,
+    provides = [DefaultInfo, SwcPluginConfigInfo],
+)
diff --git a/swc/private/swc_plugin_config_info.bzl b/swc/private/swc_plugin_config_info.bzl
@@ -0,0 +1,9 @@
+"SwcPluginConfigInfo provider"
+
+SwcPluginConfigInfo = provider(
+    doc = "Provides a configuration for an SWC plugin",
+    fields = {
+        "label": "the label of the target that created this provider",
+        "config": "the plugin configuration",
+    },
+)
diff --git a/swc/providers.bzl b/swc/providers.bzl
@@ -0,0 +1,5 @@
+"""Providers for building derivative rules"""
+
+load("//swc/private:swc_plugin_config_info.bzl", _SwcPluginConfigInfo = "SwcPluginConfigInfo")
+
+SwcPluginConfigInfo = _SwcPluginConfigInfo

Original file line number	Diff line number	Diff line change
`@@ -0,0 +1,2 @@`
	`1`	`+import { map } from "lodash";`
	`2`	`+import { sort } from "lodash2";`