1.0.3 add more functions for Hemdal.Host and tests

Author: manuel-rubio

lib/hemdal.ex

@@ -64,7 +64,7 @@ defmodule Hemdal do
   linked to the checks, see `Hemdal.Check` for further information.
 
   The events could be implemented via `GenStage`. See `Hemdal.Event` for
-  futher information.
+  further information.
 
   ## Notification
 
@@ -75,7 +75,7 @@ defmodule Hemdal do
   - `Hemdal.Notifier.Slack` is sending the event to a Slack webhook.
   - `Hemdal.Notifier.Mattermost` is sending the even to a Mattermost webhook.
 
-  See `Hemdal.Notifier` for futher information.
+  See `Hemdal.Notifier` for further information.
   """
 
   @doc """

lib/hemdal/host.ex

@@ -84,7 +84,6 @@ defmodule Hemdal.Host do
   """
   @spec start_link([Hemdal.Config.Host.t()]) :: {:ok, pid()}
   def start_link([host]) do
-    Logger.info("starting #{host.id} - #{host.name}")
     {:ok, _pid} = GenServer.start_link(__MODULE__, [host], name: via(host.id))
   end
 
@@ -141,8 +140,14 @@ defmodule Hemdal.Host do
   """
   @spec reload_all() :: :ok
   def reload_all do
-    Hemdal.Config.get_all_hosts()
-    |> Enum.each(&update_host/1)
+    config_hosts = Hemdal.Config.get_all_hosts()
+    Enum.each(config_hosts, &update_host/1)
+
+    config_ids = Enum.map(config_hosts, & &1.id)
+    running_ids = get_all()
+
+    (running_ids -- config_ids)
+    |> Enum.each(&stop/1)
   end
 
   @doc """
@@ -156,6 +161,29 @@ defmodule Hemdal.Host do
     |> Enum.each(&start/1)
   end
 
+  @doc """
+  Get all the host IDs that are running at the moment of calling this function.
+  """
+  @spec get_all() :: [host_id()]
+  def get_all do
+    @registry_name
+    |> Registry.select([{{:"$1", :"$2", :_}, [], [{{:"$1", :"$2"}}]}])
+    |> Enum.filter(fn {_key, pid} -> is_pid(pid) and Process.alive?(pid) end)
+    |> Enum.map(fn {key, _pid} -> key end)
+    |> Enum.sort()
+  end
+
+  @doc """
+  Terminate the processes related to a process ID.
+  """
+  @spec stop(host_id()) :: :ok
+  def stop(host_id) do
+    Registry.lookup(@registry_name, host_id)
+    |> Enum.each(fn {pid, _value} ->
+      DynamicSupervisor.terminate_child(@sup_name, pid)
+    end)
+  end
+
   @doc """
   Update the host configuration. If the host isn't running it's starting it
   and passing it the configuration provided as the `host` parameter. In a
@@ -187,6 +215,7 @@ defmodule Hemdal.Host do
   @impl GenServer
   @doc false
   def init([host]) do
+    Logger.info("[#{inspect(self())}] starting #{host.id} - #{host.name}")
     {:ok, %__MODULE__{host: host, max_workers: host.max_workers}}
   end
 

mix.exs

@@ -1,7 +1,7 @@
 defmodule Hemdal.MixProject do
   use Mix.Project
 
-  @version "1.0.2"
+  @version "1.0.3"
 
   def project do
     [
@@ -15,12 +15,21 @@ defmodule Hemdal.MixProject do
       description: "Hemdal Alarms/Alerts System",
       docs: docs(),
       package: package(),
+      test_coverage: coverage(),
       preferred_cli_env: [
         check: :test
       ]
     ]
   end
 
+  defp coverage do
+    [
+      ignore_modules: [
+        Hemdal.Host.Supervisor
+      ]
+    ]
+  end
+
   def application do
     [
       mod: {Hemdal.Application, []},

mix.lock

@@ -1,7 +1,7 @@
 %{
   "bunt": {:hex, :bunt, "1.0.0", "081c2c665f086849e6d57900292b3a161727ab40431219529f13c4ddcf3e7a44", [:mix], [], "hexpm", "dc5f86aa08a5f6fa6b8096f0735c4e76d54ae5c9fa2c143e5a1fc7c1cd9bb6b5"},
   "construct": {:hex, :construct, "3.0.3", "2c0d6ba6fc00cf099e146b18610d5cd45aa2e5c3dc437914c3d45f6c122402b3", [:mix], [], "hexpm", "b83c73dab2dfccf09d8e74124b1ae4797ac061ab680d3feed9a36c4d874c7947"},
-  "credo": {:hex, :credo, "1.7.11", "d3e805f7ddf6c9c854fd36f089649d7cf6ba74c42bc3795d587814e3c9847102", [:mix], [{:bunt, "~> 0.2.1 or ~> 1.0", [hex: :bunt, repo: "hexpm", optional: false]}, {:file_system, "~> 0.2 or ~> 1.0", [hex: :file_system, repo: "hexpm", optional: false]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: false]}], "hexpm", "56826b4306843253a66e47ae45e98e7d284ee1f95d53d1612bb483f88a8cf219"},
+  "credo": {:hex, :credo, "1.7.12", "9e3c20463de4b5f3f23721527fcaf16722ec815e70ff6c60b86412c695d426c1", [:mix], [{:bunt, "~> 0.2.1 or ~> 1.0", [hex: :bunt, repo: "hexpm", optional: false]}, {:file_system, "~> 0.2 or ~> 1.0", [hex: :file_system, repo: "hexpm", optional: false]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: false]}], "hexpm", "8493d45c656c5427d9c729235b99d498bd133421f3e0a683e5c1b561471291e5"},
   "decimal": {:hex, :decimal, "2.3.0", "3ad6255aa77b4a3c4f818171b12d237500e63525c2fd056699967a3e7ea20f62", [:mix], [], "hexpm", "a4d66355cb29cb47c3cf30e71329e58361cfcb37c34235ef3bf1d7bf3773aeac"},
   "dialyxir": {:hex, :dialyxir, "1.4.5", "ca1571ac18e0f88d4ab245f0b60fa31ff1b12cbae2b11bd25d207f865e8ae78a", [:mix], [{:erlex, ">= 0.2.7", [hex: :erlex, repo: "hexpm", optional: false]}], "hexpm", "b0fb08bb8107c750db5c0b324fa2df5ceaa0f9307690ee3c1f6ba5b9eb5d35c3"},
   "doctor": {:hex, :doctor, "0.22.0", "223e1cace1f16a38eda4113a5c435fa9b10d804aa72d3d9f9a71c471cc958fe7", [:mix], [{:decimal, "~> 2.0", [hex: :decimal, repo: "hexpm", optional: false]}], "hexpm", "96e22cf8c0df2e9777dc55ebaa5798329b9028889c4023fed3305688d902cd5b"},

test/hemdal/host_test.exs

@@ -0,0 +1,98 @@
+defmodule Hemdal.HostTest do
+  use ExUnit.Case, async: false
+
+  def host(id) do
+    [
+      id: Enum.random(1..1000),
+      name: "empty alert check",
+      host: [
+        id: id,
+        module: Hemdal.Host.Local,
+        name: "localhost",
+        max_workers: 1
+      ]
+    ]
+  end
+
+  setup do
+    Application.put_env(:hemdal, :config_module, Hemdal.Config.Backend.Env)
+
+    Application.put_env(:hemdal, Hemdal.Config, [
+      host("f8441510-95db-4e00-a3e0-1556bb8a778c"),
+      host("78eb75f9-2ac7-434c-a1a2-330b23c89982")
+    ])
+
+    Enum.each(Hemdal.Host.get_all(), &Hemdal.Host.stop/1)
+  end
+
+  test "start & stop host" do
+    host = Hemdal.Config.get_host_by_id!("f8441510-95db-4e00-a3e0-1556bb8a778c")
+
+    assert %Hemdal.Config.Host{
+             id: "f8441510-95db-4e00-a3e0-1556bb8a778c",
+             module: Hemdal.Host.Local
+           } = host
+
+    assert :ok = Hemdal.Host.start(host)
+    assert Hemdal.Host.exists?(host.id)
+
+    assert :ok = Hemdal.Host.stop(host.id)
+    refute Hemdal.Host.exists?(host.id)
+  end
+
+  test "get all hosts" do
+    host = Hemdal.Config.get_host_by_id!("78eb75f9-2ac7-434c-a1a2-330b23c89982")
+
+    assert :ok = Hemdal.Host.start(host)
+    assert Hemdal.Host.exists?(host.id)
+
+    assert host.id in Hemdal.Host.get_all()
+
+    assert :ok = Hemdal.Host.stop(host.id)
+    refute Hemdal.Host.exists?(host.id)
+
+    refute host.id in Hemdal.Host.get_all()
+  end
+
+  test "add one reloading all hosts" do
+    assert :ok = Hemdal.Host.reload_all()
+
+    assert ~w[
+      78eb75f9-2ac7-434c-a1a2-330b23c89982
+      f8441510-95db-4e00-a3e0-1556bb8a778c
+    ] == Hemdal.Host.get_all()
+
+    Application.put_env(:hemdal, Hemdal.Config, [
+      host("f8441510-95db-4e00-a3e0-1556bb8a778c"),
+      host("78eb75f9-2ac7-434c-a1a2-330b23c89982"),
+      host("92412973-4d6c-4c08-86ed-82d64f8ea756")
+    ])
+
+    assert :ok = Hemdal.Host.reload_all()
+
+    assert ~w[
+      78eb75f9-2ac7-434c-a1a2-330b23c89982
+      92412973-4d6c-4c08-86ed-82d64f8ea756
+      f8441510-95db-4e00-a3e0-1556bb8a778c
+    ] == Hemdal.Host.get_all()
+  end
+
+  test "remove one reloading all hosts" do
+    assert :ok = Hemdal.Host.reload_all()
+
+    assert ~w[
+      78eb75f9-2ac7-434c-a1a2-330b23c89982
+      f8441510-95db-4e00-a3e0-1556bb8a778c
+    ] == Hemdal.Host.get_all()
+
+    Application.put_env(:hemdal, Hemdal.Config, [
+      host("78eb75f9-2ac7-434c-a1a2-330b23c89982")
+    ])
+
+    assert :ok = Hemdal.Host.reload_all()
+
+    assert ~w[
+      78eb75f9-2ac7-434c-a1a2-330b23c89982
+    ] == Hemdal.Host.get_all()
+  end
+end